Using a Cell Value as a Worksheet Name in a Formula

Roy has a formula that references a cell in another workbook, as ='[Timesheets.xlsm]Week01′!L6. He would like to have the formula pick up the name of the worksheet (Week01) from another cell, so that the formula becomes more general-purpose. Roy wonders how he should change the formula so it can use whatever worksheet name is in cell B9.

The easiest way to handle this is to use the INDIRECT worksheet function. Essentially, it takes a cell address and uses it as a “pointer” and then retrieves the value from that cell. For instance, you could use the following:

=INDIRECT(L6)

This results in the value in cell L6 being fetched and used as the pointer to what you really want. Thus, if cell L6 contains “A7”, then the function returns the value of whatever is in cell A7. Interestingly, if you invoke the function in this way you get a different result:

=INDIRECT("L6")

The result is the contents of cell L6 instead of using the contents of cell L6 as a pointer.

With this information, you could easily put together an address that will work properly with the INDIRECT function:

=INDIRECT("'[Timesheets.xlsm]" & K2 & "'!L6")

This formula assumes that the name of the desired worksheet is stored in cell K2. If a valid worksheet name is not in that cell the formula returns a #REF error.

One important “gotcha” with this approach is that you’ve got to make sure that the workbook (Timesheets.xlsm) is open. INDIRECT won’t reach into an unopen workbook. If it is not open, then you’ll get a #REF error instead of the desired value.

If you want to make the formula even more general-purpose, you could pull the workbook name, worksheet name, and cell referene all from cells within your worksheet, as in this manner:

=INDIRECT("'[" & K1 & "]" & K2 & "'!" & K3)

In this instance, K1 would contain the workbook name (Timesheets.xlsm), K2 would contain the worksheet name (“Week01”), and K3 would contain the cell desired (“L6”).