Sorting by the Last Digits in Variable Length Data

Howard has a list of numbers, sometimes 6 digits, sometimes 8 digits, but the length is irrelevant as he needs to sort by the last 2 digits and then by the previous 2 digits. He tried right/middle/left types of formulas, but with having varying numbers of digits he could not make it work.

Before discussing approaches, it is important to make a few explicit assumptions about Howard’s data. In this tip I’ll assume that the data is in column A and that it consists of at least 4 digits. (Howard mentions lengths of 6 and 8 digits, so this shouldn’t be a false assumption.) It is also assumed that the only thing in column A is values made up of digits-it doesn’t contain other characters that you want ignored in your sorting.

If you wanted to use two helper columns to extract the sorting digits, then you could use the following in column B:

=RIGHT(A1,2)

The formula grabs the two right-most digits from whatever is in column A. The following could then be placed into column C:

=MID(A1, LEN(A1)-3,2)

This formula looks at the length of whatever is in A1 and uses that value as a parameter for the MID function to extract the two digits that precede the final two digits in the value.

It is important to realize that these formulas return text values, regardless of whether the values in column A are numeric or text. This is handy when either of the extracted values begin with 0; it means that instead of “5” being returned you’ll see “05” or “00” instead of “0”. If you want to make sure that numeric values are returned, then you’ll need to wrap each formula in the VALUE function:

=VALUE(RIGHT(A1,2))
=VALUE(MID(A1, LEN(A1)-3,2))

With your “key values” in columns B and C you could then perform your sort based on those values. You could also, if desired, use only a single helper column with either of these formulas in column B:

=RIGHT(A1,2)&MID(A1, LEN(A1)-3,2)
=RIGHT(A1,2)&LEFT(RIGHT(A1,4),2)

Again, these return text strings (which are just fine for sorting), but you could convert them to numeric values by wrapping them in the VALUE function:

=VALUE(RIGHT(A1,2)&MID(A1, LEN(A1)-3,2))
=VALUE(RIGHT(A1,2)&LEFT(RIGHT(A1,4),2))

Regardless of whether you work with extracted text or a numeric value in column B, you can now sort based on the column contents.