Pasting without Updating References

As you are working on a worksheet, copying and moving information from one place to another, you may wonder if there is a way to copy or move a selection without Excel changing all the references within the selection. The answer, of course, is that it depends. (Don’t you just love that about Excel?) Let’s take a look at how you can both copy and move selections in Excel.

If you are copying a selection, then Excel will update all relative references within the selection when you paste it. The solution is to make sure that all the references within the selection are absolute before doing the copy and paste. Making the changes to the formulas by hand is tedious. You can use the following macro to convert all the formulas in the selection to their absolute equivalent:

Sub ConvertToAbsolute()
    Dim c As Variant
    Application.ScreenUpdating = False
    For Each c In Selection
        c.Value = Application.ConvertFormula(c.Formula, _
          xlA1, , xlAbsolute)
    Next c
    Application.ScreenUpdating = True
End Sub

Once this macro is run, you can copy and paste the selection without Excel doing any updating to references. Once the pasting is done, you can change the references in the selection (and in the original range, if it still exists) by selecting the range and applying this macro:

Sub ConvertToRelative()
    Dim c As Variant
    Application.ScreenUpdating = False
    For Each c In Selection
        c.Value = Application.ConvertFormula(c.Formula, _
          xlA1, , xlRelative, c)
    Next c
    Application.ScreenUpdating = True
End Sub

This macro will change all formulas in the selected range to their relative equivalent. Remember that this will affect all formulas-which means that if the formulas in the range contained both relative and absolute references, then they will all be relative when this macro is done.

If you are moving a selection, then Excel does not update cell references in the move. You can move either by selecting the range and using the keyboard (pressing Ctrl+X to cut and then Ctrl+V to paste the selection) or the mouse (dragging the selection to a new location). In either case, Excel leaves the references in the selection exactly the same-relative or not-without updating.

So far I have discussed what Excel does with the references in the selection being copied or moved. What about references to the information in the selection? If you are copying, then Excel leaves references pointing to the original range. If you are moving a selection, then Excel updates references to that selection, regardless of whether they are relative or absolute. If you don’t want the information updated during a move, then the solution is to make a copy of the range and then delete the original.