# Determining If a Value is Out of Limits

Jennifer has two numbers that she needs to compare in a formula. If the second number is within 5% (plus or minus) of the first number, it is considered within limits. If the second number is outside of this range, then she needs the formula to return something such as “out of limits.”

There are a number of different ways you could approach your formula. Let’s assume that your first number is in cell A1 and that the number you want to compare to it is in cell B1. One method is to use the IF function to do your testing:

```=IF((A1-B1)>(A1*0.05),"out of limits",
IF((B1-A1)>(A1*0.05),"out of limits",
"within limits"))
```

This works fine, but the formula is a bit long. You can add the OR function to your formula to make it quite a bit shorter:

```=IF(OR(B1A1*1.05),"out of limits","within limits")
```

You could make the formula shorter still by skipping the OR function and simply doing a comparison on the absolute difference between the values:

```=IF(ABS((B1-A1)/A1)<=0.05,"within limits","out of limits")
```

Since there is division happening in this formula, it is possible that you could get an error if the value in A1 is 0. To avoid this potential problem, the formula should be modified slightly:

```=IF(A1=0,"unknown",IF(ABS((B1-A1)/A1)<=0.05,
"within limits","out of limits"))
```

If the requirement is for the values to be “within 5% of each other,” the calculation is slightly more complex:

```=IF(ABS(B1-A1)/MAX(ABS(B1),ABS(A1))>0.05,
"out of limits","within limits")
```

In this case, the MAX function is used to determine the larger of the two values in A1 and B1. It must test the absolute values of A1 and B1 because the MAX function returns the value nearest to zero if both numbers are negative.